MongoDB Atlas With Terraform - Cluster and Backup Policies

provider "mongodbatlas" {}

terraform {
  required_version = ">= 0.12"
  required_providers {
    mongodbatlas = {
      source = "mongodb/mongodbatlas"
      version = "1.14.0"
    }
  }
}

# ------------------------------------------------------------------------------
# MONGODB CLUSTER
# ------------------------------------------------------------------------------
resource "mongodbatlas_advanced_cluster" "default" {
  project_id = data.mongodbatlas_project.default.id
  name = var.name
  cluster_type = var.cluster_type
  backup_enabled = var.backup_enabled
  pit_enabled = var.pit_enabled
  mongo_db_major_version = var.mongo_db_major_version
  disk_size_gb = var.disk_size_gb

  advanced_configuration {
    fail_index_key_too_long = var.fail_index_key_too_long
    javascript_enabled = var.javascript_enabled
    minimum_enabled_tls_protocol = var.minimum_enabled_tls_protocol
    no_table_scan = var.no_table_scan
    oplog_size_mb = var.oplog_size_mb
    default_read_concern = var.default_read_concern
    default_write_concern = var.default_write_concern
    oplog_min_retention_hours = var.oplog_min_retention_hours
    transaction_lifetime_limit_seconds = var.transaction_lifetime_limit_seconds
    sample_size_bi_connector = var.sample_size_bi_connector
    sample_refresh_interval_bi_connector = var.sample_refresh_interval_bi_connector
}

  replication_specs {
    num_shards = var.cluster_type == "REPLICASET" ? null : var.num_shards
    
    dynamic "region_configs" {
      for_each = var.region_configs

      content {
        provider_name = region_configs.value.provider_name
        priority = region_configs.value.priority
        region_name = region_configs.value.region_name

        electable_specs {
          instance_size = region_configs.value.electable_specs.instance_size
          node_count = region_configs.value.electable_specs.node_count
          disk_iops = region_configs.value.electable_specs.instance_size == "M10" || region_configs.value.electable_specs.instance_size == "M20" ? null :            region_configs.value.electable_specs.disk_iops
          ebs_volume_type = region_configs.value.electable_specs.ebs_volume_type
        }

        auto_scaling {
          disk_gb_enabled = region_configs.value.auto_scaling.disk_gb_enabled
          compute_enabled = region_configs.value.auto_scaling.compute_enabled
          compute_scale_down_enabled = region_configs.value.auto_scaling.compute_scale_down_enabled
          compute_min_instance_size = region_configs.value.auto_scaling.compute_min_instance_size
          compute_max_instance_size = region_configs.value.auto_scaling.compute_max_instance_size
        }

        analytics_specs {
          instance_size = try(region_configs.value.analytics_specs.instance_size, "M10")
          node_count = try(region_configs.value.analytics_specs.node_count, 0)
          disk_iops = try(region_configs.value.analytics_specs.disk_iops, null)
         ebs_volume_type = try(region_configs.value.analytics_specs.ebs_volume_type, "STANDARD")
        }

       analytics_auto_scaling {
         disk_gb_enabled = try(region_configs.value.analytics_auto_scaling.disk_gb_enabled, null)
         compute_enabled = try(region_configs.value.analytics_auto_scaling.compute_enabled, null)
         compute_scale_down_enabled = try(region_configs.value.analytics_auto_scaling.compute_scale_down_enabled, null)
         compute_min_instance_size = try(region_configs.value.analytics_auto_scaling.compute_min_instance_size, null)
         compute_max_instance_size = try(region_configs.value.analytics_auto_scaling.compute_max_instance_size, null)
        }

       read_only_specs {
         instance_size = try(region_configs.value.read_only_specs.instance_size, "M10")
         node_count = try(region_configs.value.read_only_specs.node_count, 0)
         disk_iops = try(region_configs.value.read_only_specs.disk_iops, null)
         ebs_volume_type = try(region_configs.value.read_only_specs.ebs_volume_type, "STANDARD")
        }
      }
    }
  }

  dynamic "tags" {
    for_each = local.tags
    content {
     key = tags.key
     value = tags.value
    }
  }

  bi_connector_config {
    enabled = var.bi_connector_enabled
    read_preference = var.bi_connector_read_preference
  }

  lifecycle {
    ignore_changes = [
    disk_size_gb,
    ]
  } 
}

# ------------------------------------------------------------------------------
# MONGODB BACKUP SCHEDULE
# ------------------------------------------------------------------------------
resource "mongodbatlas_cloud_backup_schedule" "default" {
  project_id = data.mongodbatlas_project.default.id
  cluster_name = mongodbatlas_advanced_cluster.default.name
  update_snapshots = var.update_snapshots
  reference_hour_of_day = var.reference_hour_of_day
  reference_minute_of_hour = var.reference_minute_of_hour
  restore_window_days = var.restore_window_days

  policy_item_hourly {
    frequency_interval = var.policy_item_hourly_frequency_interval
    retention_unit = var.policy_item_hourly_retention_unit
    retention_value = var.policy_item_hourly_retention_value
  }

  policy_item_daily {
    frequency_interval = var.policy_item_daily_frequency_interval
    retention_unit = var.policy_item_daily_retention_unit
    retention_value = var.policy_item_daily_retention_value
  }

  policy_item_weekly {
    frequency_interval = var.policy_item_weekly_frequency_interval
    retention_unit = var.policy_item_weekly_retention_unit
    retention_value = var.policy_item_weekly_retention_value
  }

  policy_item_monthly {
    frequency_interval = var.policy_item_monthly_frequency_interval
    retention_unit = var.policy_item_monthly_retention_unit
    retention_value = var.policy_item_monthly_retention_value
  }
}

variable "name" {
description = "The name of the cluster."
type = string
}

variable "cluster_type" {
description = <<HEREDOC
Optional - Specifies the type of the cluster that you want to modify. You cannot convert
a sharded cluster deployment to a replica set deployment. Accepted values include:
REPLICASET for Replica set, SHARDED for Sharded cluster, and GEOSHARDED for Global Cluster
HEREDOC
default = "REPLICASET"
}


variable "mongo_db_major_version" {
description = <<HEREDOC
Optional - Version of the cluster to deploy. Atlas supports the following MongoDB versions
for M10+ clusters: 5.0, 6.0 or 7.0.
HEREDOC
default = "7.0"
}

variable "version_release_system" {
description = <<HEREDOC
Optional - Release cadence that Atlas uses for this cluster. This parameter defaults to LTS.
If you set this field to CONTINUOUS, you must omit the mongo_db_major_version field. Atlas accepts:
CONTINUOUS - Atlas deploys the latest version of MongoDB available for the cluster tier.
LTS - Atlas deploys the latest Long Term Support (LTS) version of MongoDB available for the cluster tier.
HEREDOC
default = "LTS"
}

  

variable "disk_size_gb" {
description = <<HEREDOC
Optional - Capacity, in gigabytes, of the host’s root volume. Increase this
number to add capacity, up to a maximum possible value of 4096 (i.e., 4 TB). This value must
be a positive integer. If you specify diskSizeGB with a lower disk size, Atlas defaults to
the minimum disk size value. Note: The maximum value for disk storage cannot exceed 50 times
the maximum RAM for the selected cluster. If you require additional storage space beyond this
limitation, consider upgrading your cluster to a higher tier.
HEREDOC
type = number
default = 10
}

variable "backup_enabled" {
description = <<HEREDOC
Optional - Flag indicating if the cluster uses Cloud Backup for backups. If true, the cluster
uses Cloud Backup for backups. The default is true.
HEREDOC
type = bool
default = true
}

variable "pit_enabled" {
description = <<HEREDOC
Optional - Flag that indicates if the cluster uses Continuous Cloud Backup. If set to true,
backup_enabled must also be set to true. The default is true.
HEREDOC
type = bool
default = true
}

variable "disk_gb_enabled" {
description = <<HEREDOC
Optional - Specifies whether disk auto-scaling is enabled. The default is true.
HEREDOC
type = bool
default = true
}

variable "region_configs" {
description = <<HEREDOC
Required - Physical location of the region. Each regionsConfig document describes
the region’s priority in elections and the number and type of MongoDB nodes Atlas
deploys to the region. You can be set that parameters:

- region_name - Optional - Physical location of your MongoDB cluster. The region you choose can affect network latency for clients accessing your databases.

- electable_nodes - Optional - Number of electable nodes for Atlas to deploy to the region. Electable nodes can become the primary and can facilitate local reads. The total number of electableNodes across all replication spec regions must total 3, 5, or 7. Specify 0 if you do not want any electable nodes in the region. You cannot create electable nodes in a region if priority is 0.

- priority - Optional - Election priority of the region. For regions with only read-only nodes, set this value to 0. For regions where electable_nodes is at least 1, each region must have a priority of exactly one (1) less than the previous region. The first region
must have a priority of 7. The lowest possible priority is 1. The priority 7 region identifies the Preferred Region of the cluster. Atlas places the primary node in the Preferred Region. Priorities 1 through 7 are exclusive - no more than one region per cluster can be assigned a given priority. Example: If you have three regions, their priorities would be 7, 6, and 5 respectively. If you added two more regions for supporting electable nodes, the priorities of those regions would be 4 and 3 respectively.

- read_only_nodes - Optional - Number of read-only nodes for Atlas to deploy to the region.
Read-only nodes can never become the primary, but can facilitate local-reads. Specify 0 if you do not want any read-only nodes in the region.

- analytics_nodes - Optional - The number of analytics nodes for Atlas to deploy to the region.
Analytics nodes are useful for handling analytic data such as reporting queries from BI Connector for Atlas. Analytics nodes are read-only, and can never become the primary. If you do not specify this option, no analytics nodes are deployed to the region.
HEREDOC
type = any
}

# ------------------------------------------------------------------------------
# MONGODB BI CONNECTOR
# ------------------------------------------------------------------------------

variable "bi_connector_enabled" {
description = <<HEREDOC
Optional - Specifies whether or not BI Connector for Atlas is enabled on the cluster.
Set to true to enable BI Connector for Atlas. Set to false to disable BI Connector for Atlas.
HEREDOC
type = bool
default = false
}

variable "bi_connector_read_preference" {
description = <<HEREDOC
Optional - Specifies the read preference to be used by BI Connector for Atlas on the cluster.
Each BI Connector for Atlas read preference contains a distinct combination of readPreference and readPreferenceTags options. For details on BI Connector for Atlas read preferences, refer to the BI Connector Read Preferences Table.
Set to "primary" to have BI Connector for Atlas read from the primary. Set to "secondary" to have BI Connector for Atlas read from a secondary member. Default if there are no analytics nodes in the cluster. Set to "analytics" to have BI Connector for Atlas read from an analytics node. Default if the cluster contains analytics nodes.
HEREDOC
type = string
default = "secondary"
}

# ------------------------------------------------------------------------------
# MONGODB ADVANCED CONFIGURATION
# ------------------------------------------------------------------------------
variable "fail_index_key_too_long" {
description = <<HEREDOC
Optional - When true, documents can only be updated or inserted if, for all indexed fields on the target collection, the corresponding index entries do not exceed 1024 bytes. When false, mongod writes documents that exceed the limit but does not index them.
HEREDOC
type = bool
default = false
}

variable "javascript_enabled" {
description = <<HEREDOC
Optional - When true, the cluster allows execution of operations that perform server-side executions of JavaScript. When false, the cluster disables execution of those operations.
HEREDOC
type = bool
default = true
}

variable "minimum_enabled_tls_protocol" {
description = <<HEREDOC
Optional - Sets the minimum Transport Layer Security (TLS) version the cluster accepts for incoming connections. Valid values are: TLS1_0, TLS1_1, TLS1_2. The default is "TLS1_2".
HEREDOC
default = "TLS1_2"
}

variable "no_table_scan" {
description = <<HEREDOC
Optional - When true, the cluster disables the execution of any query that requires a collection scan to return results. When false, the cluster allows the execution of those operations.
HEREDOC
type = bool
default = false
}

variable "oplog_size_mb" {
description = <<HEREDOC
Optional - The custom oplog size of the cluster.
Without a value that indicates that the cluster uses the default oplog size calculated by Atlas.
HEREDOC
type = number
default = null
}

variable "default_read_concern" {
description = <<HEREDOC
Optional - The default read concern for the cluster. The default is "local".
HEREDOC
default = "local"
}
  
variable "default_write_concern" {
description = <<HEREDOC
Optional - The default write concern for the cluster. The default is "majority".
HEREDOC
default = "majority"
}

variable "oplog_min_retention_hours" {
description = <<HEREDOC
Minimum retention window for cluster's oplog expressed in hours.
A value of null indicates that the cluster uses the default minimum oplog window that MongoDB Cloud calculates.
HEREDOC
type = number
default = null
}

variable "transaction_lifetime_limit_seconds" {
description = <<HEREDOC
Optional - Lifetime, in seconds, of multi-document transactions. Defaults to 60 seconds.
HEREDOC
type = number
default = 60
}

variable "sample_size_bi_connector" {
description = <<HEREDOC
Optional - Number of documents per database to sample when gathering schema information. Defaults to 100.
Available only for Atlas deployments in which BI Connector for Atlas is enabled.
HEREDOC
type = number
default = 100
}

variable "sample_refresh_interval_bi_connector" {
description = <<HEREDOC
Optional - Interval in seconds at which the mongosqld process re-samples data to create its relational schema. The default value is 300.
The specified value must be a positive integer.
Available only for Atlas deployments in which BI Connector for Atlas is enabled.
HEREDOC
type = number
default = 300
}

# ------------------------------------------------------------------------------
# MONGODB REPLICATION SPECS
# ------------------------------------------------------------------------------
variable "num_shards" {
description = <<HEREDOC
Optional - Number of shards, minimum 1.
The default is null if type is REPLICASET.
HEREDOC
type = number
default = null
}

# ------------------------------------------------------------------------------
# MONGODB BACKUP POLICY
# ------------------------------------------------------------------------------
variable "update_snapshots" {
description = <<HEREDOC
Optional - Specify true to apply the retention changes in the updated backup policy to snapshots that Atlas took previously.
HEREDOC
type = bool
default = false
}

variable "reference_hour_of_day" {
description = <<HEREDOC
Optional - Hour of the day in UTC at which Atlas takes the daily snapshots of the cluster.
HEREDOC
type = number
default = 3
}

variable "reference_minute_of_hour" {
description = <<HEREDOC
Optional - Minute of the hour in UTC at which Atlas takes the daily snapshots of the cluster.
HEREDOC
type = number
default = 30
}

variable "restore_window_days" {
description = <<HEREDOC
Optional - Number of days Atlas retains the backup snapshots in the snapshot schedule.
HEREDOC
type = number
default = 3
}

variable "policy_item_hourly_frequency_interval" {
description = <<HEREDOC
Optional - Interval, in hours, between snapshots that Atlas takes of the cluster.
HEREDOC
type = number
default = 12
}

variable "policy_item_hourly_retention_unit" {
description = <<HEREDOC
Optional - Unit of time that Atlas retains each snapshot in the hourly snapshot schedule.
HEREDOC
type = string
default = "days"
}

variable "policy_item_hourly_retention_value" {
description = <<HEREDOC
Optional - Number of units of time that Atlas retains each snapshot in the hourly snapshot schedule.
HEREDOC
type = number
default = 3
}

variable "policy_item_daily_frequency_interval" {
description = <<HEREDOC
Optional - Interval, in days, between snapshots that Atlas takes of the cluster.
HEREDOC
type = number
default = 1
}

variable "policy_item_daily_retention_unit" {
description = <<HEREDOC
Optional - Unit of time that Atlas retains each snapshot in the daily snapshot schedule.
HEREDOC
type = string
default = "days"
}

variable "policy_item_daily_retention_value" {
description = <<HEREDOC
Optional - Number of units of time that Atlas retains each snapshot in the daily snapshot schedule.
HEREDOC
type = number
default = 7
}

variable "policy_item_weekly_frequency_interval" {
description = <<HEREDOC
Optional - Interval, in weeks, between snapshots that Atlas takes of the cluster.
HEREDOC
type = number
default = 1
}

variable "policy_item_weekly_retention_unit" {
description = <<HEREDOC
Optional - Unit of time that Atlas retains each snapshot in the weekly snapshot schedule.
HEREDOC
type = string
default = "weeks"
}

variable "policy_item_weekly_retention_value" {
description = <<HEREDOC
Optional - Number of units of time that Atlas retains each snapshot in the weekly snapshot schedule.
HEREDOC
type = number
default = 4
}


variable "policy_item_monthly_frequency_interval" {
description = <<HEREDOC
Optional - Interval, in months, between snapshots that Atlas takes of the cluster.
HEREDOC
type = number
default = 1
}

variable "policy_item_monthly_retention_unit" {
description = <<HEREDOC
Optional - Unit of time that Atlas retains each snapshot in the monthly snapshot schedule.
HEREDOC
type = string
default = "months"
}


variable "policy_item_monthly_retention_value" {
description = <<HEREDOC
Optional - Number of units of time that Atlas retains each snapshot in the monthly snapshot schedule.
HEREDOC
type = number
default = 12
}

# ------------------------------------------------------------------------------
# MONGODB TAGS
# ------------------------------------------------------------------------------
variable "application" {
description = <<HEREDOC
Optional - Key-value pairs that tag and categorize the cluster for billing and organizational purposes.
HEREDOC
type = string
}

variable "environment" {
description = <<HEREDOC
Optional - Key-value pairs that tag and categorize the cluster for billing and organizational purposes.
HEREDOC
type = string
}

# ------------------------------------------------------------------------------
# MONGODB DATA
# ------------------------------------------------------------------------------
variable "project_name" {
description = <<HEREDOC
Required - The name of the Atlas project in which to create the cluster.
HEREDOC
type = string
}

locals {
  tags = {
    name = var.application
    environment = var.environment
  }
}

data "mongodbatlas_project" "default" {
name = var.project_name
}

project_name = "project-test"
name = "cluster-demo"
cluster_type = "REPLICASET"
application = "teste-cluster"
environment = "dev"
  
region_configs = [{
	provider_name = "AWS"
	region_name = "US_EAST_1"
	priority = 7
	  
	electable_specs = {
		instance_size = "M10"
		node_count = 3
		disk_iops = 120
		disk_size_gb = 10
		ebs_volume_type = "STANDARD"
	}
	
	auto_scaling = {
		disk_gb_enabled = true
		compute_enabled = true
		compute_scale_down_enabled = true
		compute_min_instance_size = "M10"
		compute_max_instance_size = "M30"
	}
}]